Xlorep DarkHelm
14-05-2008, 08:29 PM
/castsequence reset=target/dead/combat Serpent Sting, Arcane Shot, Autoshot
all it does is serpent sting and then autoshot kicks in on its own.
Ok, your macro is flawed a few ways:
reset doesn't work with "dead".
Actual options for reset are:
<number>
This is a number of seconds to force a reset after the last time the macro was used. So "reset=30" would make the macro automatically reset after 30 seconds after being pressed.
target
This resets the macro whenever you change targets.
combat
This resets the macro whenever you change from being in combat or out of combat.
shift
This resets the macro whenever you use it while pressing shift.
alt
This resets the macro whenever you use it while pressing alt.
ctrl
This resets the macro whenever you use it while pressing ctrl.
there is no spell called Autoshot. There is one called Auto Shot, but you should never need it to be in a macro unless you want to explicitly cast Auto Shot for some reason (rather than /startattack)
It is important to get the spelling of spells exactly right. Spaces included. If you fail on that, you will fail to make a macro that works.
You will automatically start auto shot whenever you cast any shot or sting that is not a Crowd Control ability (like Wyvern Sting or Scatter Shot). By casting Serpent Sting, you will initiate your Auto Shots automatically, same with Arcane Shot, Viper Sting, Scorpid Sting, Concussive Shot, Multi-Shot, etc. I believe that Volley, since it is *not* a shot but rather a AoE channeled ability, will not activate your Auto Shot.
In a similar way, if you cast Wing Clip, Raptor Strike, etc in melee, you will automatically start your auto attacks. The exception to these are Disengage which shuts off any attacks.
Cast Sequence macros don't happen all at once. They happen one after another after another.
So a command like:
/castsequence Serpent Sting, Arcane Shot
would make you cast Serpent Sting when you first press the button, and then it will switch to make it so when you press a second time, it will cast Arcane Shot. After that, it will go back to the start of the sequence, which will be Serpent Sting... etc.
So, a corrected version of your macro is:
/castsequence reset=target/combat Serpent Sting, Arcane Shot
Now, something to consider... the only thing that the sequence will separate casting these two abilities with, is the Global Cooldowns, of ~1.5 seconds between uses. So if you spam this for a fight, the sequence will be:
Cast Serpent Sting
<wait for Global Cooldown of ~1.5 seconds>
Cast Arcane Shot
<wait for Global Cooldown of ~1.5 seconds>
Cast Serpent Sting
<wait for Global Cooldown of ~1.5 seconds>
Cast Arcane Shot
<wait for Global Cooldown of ~1.5 seconds>
etc...
Something to note:
Serpent Sting's DoT lasts 15 seconds.
Arcane Shot has a 6 second cooldown (yes, that can be adjusted with talents).
Ok, so following that pattern, let's integrate these things into the above sequence I outlined:
Cast Serpent Sting
<wait for Global Cooldown of ~1.5 seconds> 1.5 seconds of Serpent Sting DoT effect completed
Cast Arcane Shot
<wait for Global Cooldown of ~1.5 seconds> ~3 seconds of Serpent Sting DoT effect completed. 4.5 seconds remain on Arcane Shot cooldown.
Cast Serpent Sting potentially wasting ~ 12 seconds of the previous Serpent Sting DoT effect, resetting timer
<wait for Global Cooldown of ~1.5 seconds> 3 seconds remain on Arcane Shot cooldown, 1.5 seconds of Serpent Sting DoT effect completed.
Wait for remaining 3 seconds of Arcane Shot cooldown, 4.5 seconds of Serpent Sting DoT effect completed.
Cast Arcane Shot
<wait for Global Cooldown of ~1.5 seconds> 6 seconds of Serpent Sting DoT effect completed, 1.5 seconds of Arcane Shot cooldown completed.
Cast Serpent Sting potentially wasting ~ 9 seconds of the previous Serpent Sting DoT effect, resetting timer
etc...
Basically, the sequence becomes dictated by the Arcane Shot cooldown, and you are wasting more than half of the Serpent Sting effect every time you hit with Serpent Sting. This is why I do not have my shots and stings on the same sequences/macros. Stings have their own duration to monitor which falls outside of the sequence for shots. I would *not* recommend a macro to be used in this manner, as it is horribly inefficient, wastes your mana, and tends to impede the flow of the Hunter abilities.
But, it is your choice. Personally, I keep my Shots on one macro, and my Stings on a separate macro. I put the stings together in a multi-faceted cast macro, because let's be honest... it isn't like you will be putting two different stings on a single target -- only one sting per hunter per target, after all. Shots logically go together, which is why I have Arcane Shot, Aimed Shot, Steady Shot, and even Scatter Shot all lumped together in a single macro, with it having a cast sequence for Arcane Shot and Steady Shot to interweave between my regular Auto Shot attacks.
As an example, I'll show how I set it up for my two hunters, who have some variation in their abilities, and it affected them.
For Sorlina, my 0/30/31 (http://www.wowarmory.com/character-talents.xml?r=Medivh&n=Sorlina) Hybrid Marksmanship/Survival hunter, her Shot macro is:
#showtooltip
/target [target=focustarget,exists]
/castsequence [nocombat,nomod:ctrl/alt][combat,mod:ctrl] Aimed Shot; [mod:alt] Scatter Shot; reset=combat Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
/petattack [nomod:shift]
The target line is just for me to easily make this be an assist macro by setting my focus (with the /focus command), and I end up assisting my focus. The last line, with /petattack on it just is my way to ensure I control exactly what my pet is attacking, and if I press shift when using the macro, my pet doesn't switch targets (I default to telling my pet to attack my target whenever I use this).
The important line in this is the castsequence line:
/castsequence [nocombat,nomod:ctrl/alt][combat,mod:ctrl] Aimed Shot; [mod:alt] Scatter Shot; reset=combat Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
What this complex thing is doing is I started with a certain sequence I created based on cooldowns. Arcane Shot has a 6 second cooldown. Steady Shot has a 1.5 second casting time. 6 divided by 1.5 is 4, which is how many Steady Shots I can shoot during the cooldown of the Arcane Shot. So, the sequence of:
/castsequence reset=combat Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
Will break down as this:
Arcane Shot
<wait for global cooldown of 1.5 seconds>
Steady Shot <casting time 1.5 seconds>
Steady Shot <casting time 1.5 seconds>
Steady Shot <casting time 1.5 seconds>
Steady Shot <casting time 1.5 seconds>
Arcane Shot
<wait for global cooldown of 1.5 seconds>
Steady Shot <casting time 1.5 seconds>
etc.
Note, technically it is possible to do a sequence with only 3 Steady Shots between Arcane Shots, since there is the 1.5 second Global Cooldown to account for after the Arcane Shot... But I found this works better for a little bit more mana efficiency.
This is the main sequence I have in the macro, and when I'm fighting, just pressing the macro button without anything, this sequence happens. I have a reset=combat on it, because when I start a new fight, I want it to start off with an Arcane Shot (explained why later).
Now, Sorlina has the Aimed Shot ability. This ability really kind of sucks because of the *long* casting time, but it is good for leading in with a fight. So, how do I handle it? Simple... if I am not in combat, I have the macro default to casting Aimed Shot. If I am in combat, it defaults to the sequence of Arcane Shot/Steady Shots I explained above. So, without pressing any thing other than the macro, my fights start with:
Aimed Shot (not in combat yet)
Arcane Shot (in combat now)
Steady Shot
Steady Shot
Steady Shot
Steady Shot
Arcane Shot
Steady Shot
etc.
I do this with the qualifiers "[nocombat,nomod:ctrl/alt][combat,mod:ctrl]" before the Aimed Shot. If I am not in combat, and not pressing ctrl or alt, or I am in combat and pressing ctrl, I fire an Aimed Shot. This mans that for my Arcane Shot & Steady Shot sequence, if I am not in combat and press ctrl, or I am in combat and not pressing ctrl or alt, I fire the Arcane Shot/Steady Shot sequence. The reason for alt being in that condition is actually because of Scatter Shot, which I'll explain next:
/castsequence [mod:alt] Scatter Shot
Scatter Shot is a form of Crowd Control... and for me, pressing Alt + a macro button is often my "oh crap" or need to rapidly switch to some emergency function/ability quickly. I use Scatter Shot to get some distance between me and a target, to drop a trap, or any other little thing (like breaking casting sequences) So, at any time, if I press Alt, I can switch to casting Scatter Shot.
Through it all, I have bound what each of the three modifiers do in this macro for Sorlina to specific functionality:
Shift: don't sent pet in to attack
Alt: Scatter Shot
Ctrl (in combat): Aimed Shot
Ctrl (out of combat): Arcane Shot & start sequence of Arcane Shot/Steady Shots.
No Alt, Ctrl, or Shift (out of combat): Aimed Shot
No Alt, Ctrl, or Shift (in combat) Arcane Shot/Steady Shot sequence.
Now, if I didn't have Steady Shot, I wouldn't need the /castsequence command, only /cast, and I could rewrite the macro as:
#showtooltip
/target [target=focustarget,exists]
/cast [nocombat,nomod:ctrl/alt][combat,mod:ctrl] Aimed Shot; [mod:alt] Scatter Shot; Arcane Shot
/petattack [nomod:shift]
If I don't have Scatter Shot, then I can write it as:
#showtooltip
/target [target=focustarget,exists]
/castsequence [nocombat,nomod:ctrl][combat,mod:ctrl] Aimed Shot; reset=combat Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
/petattack [nomod:shift]
If I don't have Aimed Shot, I can write it as:
#showtooltip
/target [target=focustarget,exists]
/castsequence [mod:alt] Scatter Shot; reset=combat Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
/petattack [nomod:shift]
And if I don't have Scatter Shot, Steady Shot, or Aimed Shot, then it is written as:
#showtooltip
/target [target=focustarget,exists]
/cast Arcane Shot
/petattack [nomod:shift]
So, in other words, it is flexible, based on whatever abilities I have as a Hunter. But I don't ever mix it with my Stings, since those function a bit differently from Shots.
One of the big reasons I have my reset=combat on the Arcane Shot/Steady Shot sequence in the macro is because Arcane Shot is instant-cast. Nopw, when I cast an Aimed Shot, I have to wait for the casting time, but the instant it fires, I can potentially also fire an Arcane Shot. Two shots that actually kind of appear to be 1 single shot. And, I've had both crit simultaneously before, which can be a pretty large amount of HP blown off my target all at once. Sure, it makes mobs usually really, really hate me... but Sorlina, being part Survival build, can hold her own in melee as well.
My Stings macro is:
#showtooltip
/cast [mod:ralt] Tranquilizing Shot; [nocombat,nomodifier][combat,mod:ctrl] Wyvern Sting; [mod:lalt] Viper Sting; [mod:shift] Scorpid Sting; Serpent Sting
I put Tranquilizing Shot on here, mainly because it is... well... more like a sting, and also the most limited use ability Hunters currently have (as it only affects one mob... in one 40-man instance... that not many people ever go to any more).
I to the same kind of switching between Wyvern Sting & Serpent Sting in this as I do with Aimed Shot & Arcane Shot/Steady Shots in the previous macro. But this way, I have a single, one-stop shopping for my various stings, without needing to do much hunting on my Action Bar.
I hope this helps.
Kojima
15-05-2008, 03:24 AM
Unfortunatly I don't have anything to add to the topic it self, but I figured that at least someone should credit, where credit is due.
Xlo, that was perhaps the most wellstructured and useful post I have ever read. Not only did you answer the question at hand, you added advice and tips on how he could do better, and improve his effectivenes.
Kudos mate.. Wish all posters (including meself) were as constructive as this...
Tunga
15-05-2008, 10:05 AM
Tranq shot works in plenty of places, here's one list I just found:
Azshara: Maws [Quest NPC]
Burning Steppes: Klinfran the Crazed [Hunter Epic Quest NPC]
Winterspring: Artorius the Doombringer [Hunter Epic Quest NPC]
Molten Core: Magmadar [Boss]
Blackwing Lair: Death Talon Seether [Trash], Chromaggus [Boss] & Flamegor [Boss]
Zul'Gurub: High Priest Thekal [Boss] & Hakkar the Soulflayer [Boss - but only if High Priest Thekal remains up]
Temple of Ahn'Qiraj: Qiraji Slayer [Trash] & Princess Huhuran [Boss]
Naxxramas: Gluth [Boss]
Terokkar Forest: Slaag [Quest NPC]
Black Morass: Aeonus [Boss]
Shadow Labyrinth: Cabal Zealot (in Demon Hound mode) [Trash]
The Arcatraz: Soul Devourer [Trash]
Underbog: Lykul Stinger [Trash]
Serpentshrine Cavern: Tidewalker Warrior [Trash] & Underbog Colossus [Trash]
Hyjal Summit: Ghoul [Trash]
Black Temple: Leviathan [Trash], Ashtongue Feral Spirit [Trash], Bonechewer Brawler [Trash] & Hand of Gorefiend [Trash]
Zul'aman: Amani Bear [Trash], Amani Bear Mount [Trash], Amani Dragonhawk [Trash] & Halazzi [Boss]
Sunwell Plateau: Cataclysm Hound [Trash]
vBulletin® v3.8.4, Copyright ©2000-2009, Jelsoft Enterprises Ltd.